shithub: mc

ref: b941cdfdf1940e4a64492daf1a15d921c32f2dc2
dir: /lib/thread/condvar+linux.myr/

use std
use sys

use "atomic"
use "common"
use "mutex"

pkg thread =
	type cond = struct
		_mtx	: mutex#
		_seq	: int32
	;;

	const mkcond	: (mtx : mutex# -> cond)
	const condwait	: (cond : cond# -> void)
	const condsignal	: (cond : cond# -> void)
	const condbroadcast	: (cond : cond# -> void)
;;

const mkcond = {mtx
	-> [._mtx = mtx, ._seq = 0]
}

const condwait = {cond
	var seq
	var mtx

	mtx = cond._mtx
	seq = cond._seq
	mtxunlock(mtx)

	/*
	FIXME?: `futex` can be interrupted but `condwait` should always be done
	in a loop anyway.
	*/
	sys.futex(&cond._seq, sys.Futexwait | sys.Futexpriv, seq, Zptr, Zptr, 0)

	/*
	We need to atomically set the mutex to contended. This allows us to
	pass responsibility for waking up the potential other waiters on to the
	unlocker of the mutex.
	*/
	mtxcontended(mtx)
}

const condsignal = {cond : cond#
	xadd(&cond._seq, 1)
	sys.futex(&cond._seq, sys.Futexwake | sys.Futexpriv, 1, Zptr, Zptr, 0)
}

const condbroadcast = {cond : cond#
	xadd(&cond._seq, 1)
	/*
	The futex docs seem to be broken -- the timeout parameter seems to be
	used for the number of threads to move, and is not ignored when
	requeueing
	*/
	sys.futex(&cond._seq, sys.Futexrequeue | sys.Futexpriv,
		1, (0x7fffffff : sys.timespec#),
		(&cond._mtx._state : int32#), 0)
}